AnsweredAssumed Answered

Check comms for connection?

Question asked by Shako on Jul 26, 2011
Latest reply on Jul 29, 2011 by hognala

Like • Show 0 Likes0
Comment • 1

Hi All

How can i in VBA check all the Serial Ports to see which one the Multimeter is connected to?
Without using the dialog.
I would like to automate this process so the end user doe not have to deal with this.

No one else has this question

Outcomes

1 Reply

hognala Jul 29, 2011 2:45 PM
Mark Correct
Correct Answer
To check and see what COM ports your PC has, you can check with WMI, using the following code. That will put the names of the serial ports in the first column of the first Worksheet.


    Dim i As Integer
    i = 1

    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\WMI")

    Set colItems = objWMIService.ExecQuery("Select * from MSSerial_PortName")

    For Each objItem In colItems
        Cells(i, 1) = objItem.PortName
        i = i + 1
    Next


If you want to be able to check and see if the DMM is actually at one of those addresses, you need to open a connection to it and send a *IDN? to see if anything responds. You will also need to specify the Serial parameters that the instrument is setup for.

Here's a code fragment that will find the COM ports, open them and try to talk to an instrument. Make sure that you add a Reference to VISA COM before trying run Find34410OnSerial()

Public Sub Find34401OnSerial()
    Dim i As Integer
    i = 1

    strComputer = "."
    Set objWMIService = GetObject("winmgmts:" _
        & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\WMI")

    Set colItems = objWMIService.ExecQuery("Select * from MSSerial_PortName")

    For Each objItem In colItems
        Call CheckFor34401("ASRL" + Mid(objItem.PortName, 4) + "::INSTR")
    Next

End Sub
Private Function CheckFor34401(Address As String)

    Dim globalResourceManager As New ResourceManager
    Dim serial As ISerial
    Dim message As IMessage

On Error GoTo Err


    Dim identification As String


    Set serial = globalResourceManager.Open(Address, NO_LOCK, 0, "")
    serial.BaudRate = 9600
    serial.FlowControl = ASRL_FLOW_DTR_DSR
    serial.Parity = ASRL_PAR_NONE
    serial.DataBits = 8
    serial.Timeout = 500

    Set message = serial

    message.WriteString ("*IDN?" + vbLf)
    identification = ""
    identification = message.ReadString(100)

    If (InStr(identification, "34401") <> 0) Then
        Call MsgBox(identification + " found on " + Address)
    End If

    Call message.Close
Err:

End Function
Like • Show 0 Likes0
Actions

Check comms for connection?

Outcomes

Related Content

Recommended Content